Shader "UsayaLib/3D/Unlit/FadeRimTexture" {
    Properties {
        _MainTex ("Texture", 2D) = "white" {}
        _Color ("Texture Color", Color) = (1, 1, 1, 1)
        [KeywordEnum(Multiply, Additive)] _RimBlendMode("Rim Blend Mode", Int) = 0
        _RimColor ("Rim Color", Color) = (1, 1, 1, 1)
        _Size ("Size", Range(0, 1)) = 0.5
        _Add ("Add", Range(0, 1)) = 0
        _Magnification ("Magnification", float) = 1
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog
            #pragma multi_compile _RIMBLENDMODE_MULTIPLY _RIMBLENDMODE_ADDITIVE

            #include "UnityCG.cginc"

            struct appdata {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 uv : TEXCOORD0;
            };

            struct v2f {
                float4 vertex : SV_POSITION;
                float4 color : TEXCOORD0;
                float2 uv : TEXCOORD1;
                UNITY_FOG_COORDS(1)
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Color;
            fixed4 _RimColor;
            float _Size;
            float _Add;
            float _Magnification;

            v2f vert(appdata v){
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                float3 viewDir = normalize(ObjSpaceViewDir(v.vertex));
                float rim = 1 - saturate(dot(viewDir, v.normal) - _Add);
                o.color = smoothstep(1 - _Size, 1.0, rim) * _RimColor * _Magnification;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target {
                fixed4 color = tex2D(_MainTex, i.uv) * _Color;
#ifdef _RIMBLENDMODE_ADDITIVE
                color.rgb += i.color.rgb * i.color.a;
#else
                color.rgb = color.rgb * (1 - i.color.a) + i.color.rgb * i.color.a;
#endif
                UNITY_APPLY_FOG(i.fogCoord, color);
                return color;
            }
            ENDCG
        }
    }
}